Added project structure

.gitmodules

@@ -0,0 +1,51 @@
+[submodule "3rdparty/Quazip"]
+	path = 3rdparty/Quazip
+	url = https://github.com/0xFEEDC0DE64/Quazip.git
+[submodule "libs/DbCoreLib"]
+	path = libs/DbCoreLib
+	url = https://github.com/0xFEEDC0DE64/DbCoreLib.git
+[submodule "libs/DbGuiLib"]
+	path = libs/DbGuiLib
+	url = https://github.com/0xFEEDC0DE64/DbGuiLib.git
+[submodule "libs/unittests/TstFixedSizeMatrix"]
+	path = libs/unittests/TstFixedSizeMatrix
+	url = https://github.com/0xFEEDC0DE64/TstFixedSizeMatrix.git
+[submodule "DbDatabaseTree"]
+	path = DbDatabaseTree
+	url = https://github.com/0xFEEDC0DE64/DbDatabaseTree.git
+[submodule "DbHashCracker"]
+	path = DbHashCracker
+	url = https://github.com/0xFEEDC0DE64/DbHashCracker.git
+[submodule "DbMessaging"]
+	path = DbMessaging
+	url = https://github.com/0xFEEDC0DE64/DbMessaging.git
+[submodule "DbNeuralNet"]
+	path = DbNeuralNet
+	url = https://github.com/0xFEEDC0DE64/DbNeuralNet.git
+[submodule "DbPathFinder"]
+	path = DbPathFinder
+	url = https://github.com/0xFEEDC0DE64/DbPathFinder.git
+[submodule "DbPicSync"]
+	path = DbPicSync
+	url = https://github.com/0xFEEDC0DE64/DbPicSync.git
+[submodule "DbRadioDumper"]
+	path = DbRadioDumper
+	url = https://github.com/0xFEEDC0DE64/DbRadioDumper.git
+[submodule "DbSerialServer"]
+	path = DbSerialServer
+	url = https://github.com/0xFEEDC0DE64/DbSerialServer.git
+[submodule "DbSketch"]
+	path = DbSketch
+	url = https://github.com/0xFEEDC0DE64/DbSketch.git
+[submodule "DbTernaryClock"]
+	path = DbTernaryClock
+	url = https://github.com/0xFEEDC0DE64/DbTernaryClock.git
+[submodule "DbTictactoe"]
+	path = DbTictactoe
+	url = https://github.com/0xFEEDC0DE64/DbTictactoe.git
+[submodule "DbWebserver"]
+	path = DbWebserver
+	url = https://github.com/0xFEEDC0DE64/DbWebserver.git
+[submodule "DbZeiterfassung"]
+	path = DbZeiterfassung
+	url = https://github.com/0xFEEDC0DE64/DbZeiterfassung.git

3rdparty/3rdparty.pro

@@ -0,0 +1,3 @@
+TEMPLATE = subdirs
+
+SUBDIRS += Quazip

DbSoftware.pro

@@ -0,0 +1,27 @@
+TEMPLATE = subdirs
+
+SUBDIRS += 3rdparty \
+           DbDatabaseTree \
+           DbHashCracker \
+           DbMessaging \
+           DbNeuralNet \
+           DbPathFinder \
+           DbPicSync \
+           DbRadioDumper \
+           DbSerialServer \
+           DbSketch \
+           DbTernaryClock \
+           DbTictactoe \
+           DbWebserver \
+           DbZeiterfassung \
+           libs
+
+OTHER_FILES += app.pri \
+               lib.pri \
+               project.pri
+
+DbTernaryClock.depends += libs
+DbZeiterfassung.depends += DbSketch libs
+
+include(installs.pri)
+win32: include(installs_win32.pri)

app.pri

@@ -0,0 +1,4 @@
+TEMPLATE = app
+CONFIG -= app_bundle
+DESTDIR = $${OUT_PWD}/$${PROJECT_ROOT}/bin
+include(project.pri)

installs.pri

@@ -0,0 +1,14 @@
+qtTranslationsInstall.path = $${OUT_PWD}/bin/translations
+qtTranslationsInstall.files = $$[QT_INSTALL_TRANSLATIONS]/qt_en.qm \
+                              $$[QT_INSTALL_TRANSLATIONS]/qtbase_en.qm \
+                              $$[QT_INSTALL_TRANSLATIONS]/qtmultimedia_en.qm \
+                              $$[QT_INSTALL_TRANSLATIONS]/qtquick1_en.qm \
+                              $$[QT_INSTALL_TRANSLATIONS]/qtscript_en.qm \
+                              $$[QT_INSTALL_TRANSLATIONS]/qtxmlpatterns_en.qm \
+                              $$[QT_INSTALL_TRANSLATIONS]/qt_de.qm \
+                              $$[QT_INSTALL_TRANSLATIONS]/qtbase_de.qm \
+                              $$[QT_INSTALL_TRANSLATIONS]/qtmultimedia_de.qm \
+                              $$[QT_INSTALL_TRANSLATIONS]/qtquick1_de.qm \
+                              $$[QT_INSTALL_TRANSLATIONS]/qtscript_de.qm \
+                              $$[QT_INSTALL_TRANSLATIONS]/qtxmlpatterns_de.qm
+INSTALLS += qtTranslationsInstall

installs_win32.pri

@@ -0,0 +1,28 @@
+CONFIG(debug, release|debug): DEBUG_SIGN = d
+
+qtLibsInstall.path = $${OUT_PWD}/bin
+qtLibsInstall.files = win32/Qt.conf \
+                      $$[QT_INSTALL_BINS]/Qt5Core$${DEBUG_SIGN}.dll \
+                      $$[QT_INSTALL_BINS]/Qt5Gui$${DEBUG_SIGN}.dll \
+                      $$[QT_INSTALL_BINS]/Qt5Network$${DEBUG_SIGN}.dll \
+                      $$[QT_INSTALL_BINS]/Qt5Widgets$${DEBUG_SIGN}.dll \
+                      $$[QT_INSTALL_BINS]/libgcc_s_dw2-1.dll \
+                      $$[QT_INSTALL_BINS]/libstdc++-6.dll \
+                      $$[QT_INSTALL_BINS]/libwinpthread-1.dll
+INSTALLS += qtLibsInstall
+
+qtImageFormatsInstall.path = $${OUT_PWD}/bin/plugins/imageformats
+qtImageFormatsInstall.files = $$[QT_INSTALL_PLUGINS]/imageformats/qgif$${DEBUG_SIGN}.dll \
+                              $$[QT_INSTALL_PLUGINS]/imageformats/qicns$${DEBUG_SIGN}.dll \
+                              $$[QT_INSTALL_PLUGINS]/imageformats/qico$${DEBUG_SIGN}.dll \
+                              $$[QT_INSTALL_PLUGINS]/imageformats/qjpeg$${DEBUG_SIGN}.dll \
+                              $$[QT_INSTALL_PLUGINS]/imageformats/qsvg$${DEBUG_SIGN}.dll \
+                              $$[QT_INSTALL_PLUGINS]/imageformats/qtga$${DEBUG_SIGN}.dll \
+                              $$[QT_INSTALL_PLUGINS]/imageformats/qtiff$${DEBUG_SIGN}.dll \
+                              $$[QT_INSTALL_PLUGINS]/imageformats/qwbmp$${DEBUG_SIGN}.dll \
+                              $$[QT_INSTALL_PLUGINS]/imageformats/qwebp$${DEBUG_SIGN}.dll
+INSTALLS += qtImageFormatsInstall
+
+qtPlatformsInstall.path = $${OUT_PWD}/bin/plugins/platforms
+qtPlatformsInstall.files = $$[QT_INSTALL_PLUGINS]/platforms/qwindows$${DEBUG_SIGN}.dll
+INSTALLS += qtPlatformsInstall

lib.pri

@@ -0,0 +1,4 @@
+TEMPLATE = lib
+win32: DESTDIR = $${OUT_PWD}/$${PROJECT_ROOT}/bin
+else: DESTDIR = $${OUT_PWD}/$${PROJECT_ROOT}/lib
+include(project.pri)

libs/libs.pro

@@ -0,0 +1,7 @@
+TEMPLATE = subdirs
+
+SUBDIRS += DbCoreLib \
+           DbGuiLib \
+           unittests
+
+unittests.depends += DbCoreLib

libs/unittests/unittests.pro

@@ -0,0 +1,3 @@
+TEMPLATE = subdirs
+
+SUBDIRS += TstFixedSizeMatrix

project.pri

@@ -0,0 +1,76 @@
+CONFIG += qt warn_on depend_includepath c++14
+
+QMAKE_TARGET_PRODUCT = "DbSoftware"
+QMAKE_TARGET_DESCRIPTION = "$$TARGET"
+QMAKE_TARGET_COMPANY = "brunner.ninja"
+QMAKE_TARGET_COPYRIGHT = "Copyright (C) by feedc0de"
+
+DEFINES += QT_DEPRECATED_WARNINGS \
+           QT_DISABLE_DEPRECATED_BEFORE=0x060000 \
+           QT_MESSAGELOGCONTEXT
+
+!isEmpty(DBLIBS) {
+    win32: LIBS += -L$${OUT_PWD}/$${PROJECT_ROOT}/bin
+    else: LIBS += -Wl,-rpath=\\\$$ORIGIN/../lib -L$${OUT_PWD}/$${PROJECT_ROOT}/lib
+}
+
+for(DBLIB, DBLIBS) {
+    equals(DBLIB, "dbcore") {
+        LIBS += -ldbcore
+
+        INCLUDEPATH += $$PWD/libs/DbCoreLib
+        DEPENDPATH += $$PWD/libs/DbCoreLib
+    } else: equals(DBLIB, "dbgui") {
+        LIBS += -ldbgui
+
+        INCLUDEPATH += $$PWD/libs/DbGuiLib
+        DEPENDPATH += $$PWD/libs/DbGuiLib
+    } else: equals(DBLIB, "messaginglib") {
+        LIBS += -lmessaginglib
+
+        INCLUDEPATH += $$PWD/DbMessaging/messaginglib
+        DEPENDPATH += $$PWD/DbMessaging/messaginglib
+    } else: equals(DBLIB, "neuralnetlib") {
+        LIBS += -lneuralnetlib
+
+        INCLUDEPATH += $$PWD/DbNeuralNet/neuralnetlib
+        DEPENDPATH += $$PWD/DbNeuralNet/neuralnetlib
+    } else: equals(DBLIB, "sketchlib") {
+        LIBS += -lsketchlib
+
+        INCLUDEPATH += $$PWD/DbSketch/sketchlib
+        DEPENDPATH += $$PWD/DbSketch/sketchlib
+    } else: equals(DBLIB, "webserverlib") {
+        LIBS += -lwebserverlib
+
+        INCLUDEPATH += $$PWD/DbWebserver/webserverlib
+        DEPENDPATH += $$PWD/DbWebserver/webserverlib
+    } else: equals(DBLIB, "zeiterfassungcore") {
+        LIBS += -lzeiterfassungcore
+
+        INCLUDEPATH += $$PWD/DbZeiterfassung/zeiterfassungcorelib
+        DEPENDPATH += $$PWD/DbZeiterfassung/zeiterfassungcorelib
+    } else: equals(DBLIB, "zeiterfassunggui") {
+        LIBS += -lzeiterfassunggui
+
+        INCLUDEPATH += $$PWD/DbZeiterfassung/zeiterfassungguilib
+        DEPENDPATH += $$PWD/DbZeiterfassung/zeiterfassungguilib
+    } else: equals(DBLIB, "quazip") {
+        LIBS += -lquazip
+
+        INCLUDEPATH += $$PWD/3rdparty/Quazip
+        DEPENDPATH += $$PWD/3rdparty/Quazip
+    } else: message("ERROR: Unknown dblib $$DBLIB")
+}
+
+isEmpty(QMAKE_LRELEASE) {
+    win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\lrelease.exe
+    else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
+}
+
+lrelease.input = TRANSLATIONS
+lrelease.output = $${OUT_PWD}/$${PROJECT_ROOT}/bin/translations/${QMAKE_FILE_BASE}.qm
+lrelease.commands = $${QMAKE_LRELEASE} ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_OUT}
+lrelease.CONFIG += no_link
+QMAKE_EXTRA_COMPILERS += lrelease
+PRE_TARGETDEPS += compiler_lrelease_make_all