Support make install also on OS X

It can be helpful, is not much effort, and parts did not restrict the
install target to non-OS X already.

Change-Id: I3501f37f089e981cf3f72d9250c9b9161d1565d6
Reviewed-by: Jake Petroules <jake.petroules@qt.io>

doc/doc.pri

@@ -66,7 +66,6 @@ dev_html_docs_online.depends += $$DEV_HELP_DEP_FILES
 dev_qch_docs.commands = $$HELPGENERATOR -o \"$$DEV_QCH_FILE\" $$DEV_QHP_FILE
 dev_qch_docs.depends += dev_html_docs
 
-!macx {
 inst_qch_docs.files = $$QCH_FILE
 inst_qch_docs.path = $$INSTALL_DOC_PATH
 inst_qch_docs.CONFIG += no_check_exist no_default_install
@@ -79,7 +78,6 @@ dev_qch_docs.depends += dev_html_docs
 
 install_docs.depends = install_inst_qch_docs install_inst_dev_qch_docs
 QMAKE_EXTRA_TARGETS += install_docs
-}
 
 docs_online.depends = html_docs_online dev_html_docs_online
 docs.depends = qch_docs dev_qch_docs

qtcreator.pri

@@ -93,6 +93,14 @@ osx {
 
     LINK_LIBRARY_PATH = $$IDE_APP_BUNDLE/Contents/Frameworks
     LINK_PLUGIN_PATH  = $$IDE_APP_BUNDLE/Contents/PlugIns
+
+    INSTALL_LIBRARY_PATH = $$QTC_PREFIX/$${IDE_APP_TARGET}.app/Contents/Frameworks
+    INSTALL_PLUGIN_PATH  = $$QTC_PREFIX/$${IDE_APP_TARGET}.app/Contents/PlugIns
+    INSTALL_LIBEXEC_PATH = $$QTC_PREFIX/$${IDE_APP_TARGET}.app/Contents/Resources
+    INSTALL_DATA_PATH    = $$QTC_PREFIX/$${IDE_APP_TARGET}.app/Contents/Resources
+    INSTALL_DOC_PATH     = $$INSTALL_DATA_PATH/doc
+    INSTALL_BIN_PATH     = $$QTC_PREFIX/$${IDE_APP_TARGET}.app/Contents/MacOS
+    INSTALL_APP_PATH     = $$QTC_PREFIX/
 } else {
     contains(TEMPLATE, vc.*):vcproj = 1
     IDE_APP_TARGET   = qtcreator
@@ -123,6 +131,7 @@ osx {
     INSTALL_DATA_PATH    = $$QTC_PREFIX/share/qtcreator
     INSTALL_DOC_PATH     = $$QTC_PREFIX/share/doc/qtcreator
     INSTALL_BIN_PATH     = $$QTC_PREFIX/bin
+    INSTALL_APP_PATH     = $$QTC_PREFIX/bin
 }
 
 INCLUDEPATH += \

qtcreatordata.pri

@@ -34,10 +34,8 @@ defineReplace(stripStaticBase) {
         QMAKE_EXTRA_COMPILERS += copy2build
     }
 
-    !osx {
     static.files = $$STATIC_FILES
     static.base = $$STATIC_BASE
     static.path = $$STATIC_INSTALL_BASE
     INSTALLS += static
 }
-}

share/qtcreator/qml/qmlpuppet/qml2puppet/qml2puppet.pri

@@ -28,7 +28,8 @@ unix:!openbsd:!osx: LIBS += -lrt # posix shared memory
 osx {
     CONFIG -= app_bundle
     QMAKE_LFLAGS += -Wl,-sectcreate,__TEXT,__info_plist,$$system_quote($$PWD/Info.plist)
-} else {
-    target.path  = $$INSTALL_LIBEXEC_PATH
-    INSTALLS    += target
 }
+
+osx:  target.path = $$INSTALL_LIBEXEC_PATH/qmldesigner
+else: target.path = $$INSTALL_LIBEXEC_PATH
+INSTALLS += target

share/qtcreator/translations/translations.pro

@@ -123,7 +123,7 @@ updateqm.name = LRELEASE ${QMAKE_FILE_IN}
 updateqm.CONFIG += no_link
 QMAKE_EXTRA_COMPILERS += updateqm
 
-qmfiles.files = $$prependAll(LANGUAGES, $$OUT_PWD/qtcreator_,.qm)
+qmfiles.files = $$prependAll(LANGUAGES, $$IDE_DATA_PATH/translations/qtcreator_,.qm)
 qmfiles.path = $$INSTALL_DATA_PATH/translations
 qmfiles.CONFIG += no_check_exist
 INSTALLS += qmfiles

src/app/app.pro

@@ -2,7 +2,7 @@ include(../../qtcreator.pri)
 include(../shared/qtsingleapplication/qtsingleapplication.pri)
 
 TEMPLATE = app
-CONFIG += qtc_runnable
+CONFIG += qtc_runnable sliced_bundle
 TARGET = $$IDE_APP_TARGET
 DESTDIR = $$IDE_APP_PATH
 VERSION = $$QTCREATOR_VERSION
@@ -21,8 +21,6 @@ QT_BREAKPAD_ROOT_PATH = $$(QT_BREAKPAD_ROOT_PATH)
 }
 win32 {
     RC_FILE = qtcreator.rc
-    target.path = $$INSTALL_BIN_PATH
-    INSTALLS += target
 } else:macx {
     LIBS += -framework CoreFoundation
     ASSETCATALOG.files = $$PWD/qtcreator.xcassets
@@ -40,13 +38,20 @@ win32 {
         ASSETCATALOG.input = ASSETCATALOG.files
         ASSETCATALOG.CONFIG += no_link target_predeps
         QMAKE_EXTRA_COMPILERS += ASSETCATALOG
+        icns.files = \
+            $$IDE_DATA_PATH/qtcreator.icns \
+            $$IDE_DATA_PATH/prifile.icns \
+            $$IDE_DATA_PATH/profile.icns
+        icns.path = $$INSTALL_DATA_PATH
+        icns.CONFIG += no_check_exist
+        INSTALLS += icns
     }
     QMAKE_INFO_PLIST = Info.plist
-} else {
-    target.path  = $$INSTALL_BIN_PATH
-    INSTALLS    += target
 }
 
+target.path = $$INSTALL_APP_PATH
+INSTALLS += target
+
 DISTFILES += qtcreator.rc \
     Info.plist \
     $$PWD/app_version.h.in

src/plugins/qmldesigner/plugindestdir.pri

@@ -1,7 +1,7 @@
-macx {
+osx:  DESIGNER_PATH = QmlDesigner
-  DESTDIR = $$IDE_PLUGIN_PATH/QmlDesigner
+else: DESIGNER_PATH = qmldesigner
-} else {
+
-  DESTDIR = $$IDE_PLUGIN_PATH/qmldesigner
+DESTDIR = $$IDE_PLUGIN_PATH/$$DESIGNER_PATH
-  target.path  = $$INSTALL_PLUGIN_PATH/qmldesigner
+
+target.path = $$INSTALL_PLUGIN_PATH/$$DESIGNER_PATH
 INSTALLS += target
-}

src/qtcreatorlibrary.pri

@@ -22,7 +22,6 @@ CONFIG += shared dll
 
 contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
 
-!macx {
 win32 {
     dlltarget.path = $$INSTALL_BIN_PATH
     INSTALLS += dlltarget
@@ -30,4 +29,3 @@ contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
     target.path = $$INSTALL_LIBRARY_PATH
     INSTALLS += target
 }
-}

src/qtcreatorplugin.pri

@@ -93,10 +93,8 @@ TEMPLATE = lib
 CONFIG += plugin plugin_with_soname
 linux*:QMAKE_LFLAGS += $$QMAKE_LFLAGS_NOUNDEF
 
-!macx {
 target.path = $$INSTALL_PLUGIN_PATH
 INSTALLS += target
-}
 
 MIMETYPES = $$_PRO_FILE_PWD_/$${TARGET}.mimetypes.xml
 exists($$MIMETYPES):DISTFILES += $$MIMETYPES

src/tools/3rdparty/iossim/iossim.pro

@@ -55,3 +55,6 @@ HEADERS += \
 
 DISTFILES = IOSSIM_LICENSE \
   Info.plist
+
+target.path = $$INSTALL_LIBEXEC_PATH/ios
+INSTALLS += target

src/tools/3rdparty/iossim_1_8_2/iossim_1_8_2.pro

@@ -53,3 +53,6 @@ HEADERS += \
 
 DISTFILES = IOSSIM_LICENSE \
   Info.plist
+
+target.path = $$INSTALL_LIBEXEC_PATH/ios
+INSTALLS += target

src/tools/iostool/iostool.pro

@@ -28,3 +28,6 @@ HEADERS += \
     iosdevicemanager.h
 
 DISTFILES += Info.plist
+
+target.path = $$INSTALL_LIBEXEC_PATH/ios
+INSTALLS += target