Add Qt 5 libraries to .pro files.

Make Qt Creator compile with Qt 5 after using fixqt4headers.pl. Change-Id: I74ca51d562f49378b40103b79848f5dd3b11e77e Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@nokia.com> Reviewed-by: Eike Ziller <eike.ziller@nokia.com>
2011-11-23 11:31:09 +01:00
parent 2ee7a56bdf
commit b0eff051c1
24 changed files with 54 additions and 22 deletions
--- a/qtcreator.pri
+++ b/qtcreator.pri
@@ -154,3 +154,8 @@ win32-msvc* {
    #Don't warn about sprintf, fopen etc being 'unsafe'
    DEFINES += _CRT_SECURE_NO_WARNINGS
 }
+
+qt:greaterThan(QT_MAJOR_VERSION, 4) {
+    contains(QT, gui): QT += widgets
+    contains(QT, declarative): QT += qtquick1
+}
--- a/src/libs/qtcomponents/styleitem/styleitem.pro
+++ b/src/libs/qtcomponents/styleitem/styleitem.pro
@@ -2,6 +2,7 @@ TEMPLATE = lib
 CONFIG += qt plugin
 QT += declarative
 QT += script
+greaterThan(QT_MAJOR_VERSION, 4): QT += widgets qtquick1

 TARGET  = styleplugin
 include(../../../../qtcreator.pri)
--- a/src/libs/utils/process_ctrlc_stub.pro
+++ b/src/libs/utils/process_ctrlc_stub.pro
@@ -1,14 +1,14 @@
 !win32: error("process_ctrlc_stub is Windows only")

+CONFIG    -= qt
+CONFIG    += console warn_on
+
 include(../../../qtcreator.pri)

 TEMPLATE  = app
 TARGET    = qtcreator_ctrlc_stub
 DESTDIR   = $$IDE_LIBEXEC_PATH

-QT        =
-CONFIG    += console warn_on
-
 SOURCES   += process_ctrlc_stub.cpp
 LIBS      += -luser32 -lshell32

--- a/src/libs/utils/process_stub.pro
+++ b/src/libs/utils/process_stub.pro
@@ -1,12 +1,12 @@
+CONFIG          += warn_on console use_c_linker
+CONFIG          -= qt app_bundle
+
 include(../../../qtcreator.pri)

 TEMPLATE        = app
 TARGET          = qtcreator_process_stub
 DESTDIR         = $$IDE_LIBEXEC_PATH

-CONFIG          += warn_on console use_c_linker
-CONFIG          -= qt app_bundle
-
 build_all:!build_pass {
    CONFIG -= build_all
    CONFIG += release
--- a/src/libs/utils/utils-lib.pri
+++ b/src/libs/utils/utils-lib.pri
@@ -7,7 +7,6 @@ dll {
 INCLUDEPATH += $$PWD
 QT += network

-
 win32-msvc* {
    # disable warnings caused by botan headers
    QMAKE_CXXFLAGS += -wd4250 -wd4290
--- a/src/libs/utils/utils.pro
+++ b/src/libs/utils/utils.pro
@@ -9,7 +9,13 @@ include(utils_dependencies.pri)

 include(utils-lib.pri)
 # Needed for QtCore/private/qwineventnotifier_p.h
-win32:include(../../private_headers.pri)
+win32 {
+    greaterThan(QT_MAJOR_VERSION, 4) {
+        QT += core-private
+    } else {
+        include(../../private_headers.pri)
+    }
+}

 HEADERS += \
    proxyaction.h
--- a/src/plugins/coreplugin/coreplugin.pro
+++ b/src/plugins/coreplugin/coreplugin.pro
@@ -4,6 +4,8 @@ DEFINES += CORE_LIBRARY
 QT += network \
    script \
    sql
+greaterThan(QT_MAJOR_VERSION, 4): QT += printsupport
+
 CONFIG += help
 include(../../qtcreatorplugin.pri)
 include(../../libs/utils/utils.pri)
--- a/src/plugins/debugger/lldb/guest/qtcreator-lldb.pro
+++ b/src/plugins/debugger/lldb/guest/qtcreator-lldb.pro
@@ -3,6 +3,8 @@ WITH_LLDB = $$(WITH_LLDB)
 !macx: error (This can only be built on mac)
 !exists($${WITH_LLDB}/include/lldb/lldb-enumerations.h): error(please see the README for build instructions)

+QT = core network
+
 include(../../../../../qtcreator.pri)
 TEMPLATE = app
 CONFIG  -= app_bundle
@@ -12,8 +14,6 @@ DEPENDPATH += . .. ../.. ../../..  ../../../../libs
 INCLUDEPATH += . .. ../.. ../../.. ../../../../libs
 DESTDIR  = $$IDE_LIBEXEC_PATH

-QT = core network
-
 MOC_DIR=.tmp
 OBJECTS_DIR=.tmp

--- a/src/plugins/designer/designer.pro
+++ b/src/plugins/designer/designer.pro
@@ -13,6 +13,7 @@ minQtVersion(5, 0, 0) {
    CONFIG += designer
 #   -- Fixme: Make tools available
    INCLUDEPATH += $$QMAKE_INCDIR_QT/../../qttools/include
+    QT += printsupport
 } else {
    # -- figure out shared dir location
    !exists($$[QT_INSTALL_HEADERS]/QtDesigner/private/qdesigner_integration_p.h) {
--- a/src/plugins/help/help.pro
+++ b/src/plugins/help/help.pro
@@ -1,6 +1,11 @@
 TEMPLATE = lib
 TARGET = Help
+
 QT += network
+greaterThan(QT_MAJOR_VERSION, 4) {
+    QT += printsupport
+    DEFINES += QT_NO_WEBKIT
+}

 INCLUDEPATH += $$PWD

--- a/src/plugins/qmlprofiler/qmlprofiler.pro
+++ b/src/plugins/qmlprofiler/qmlprofiler.pro
@@ -3,6 +3,8 @@ TARGET = QmlProfiler

 DEFINES += PROFILER_LIBRARY

+QT += network script declarative
+
 include(../../qtcreatorplugin.pri)
 include(../../plugins/coreplugin/coreplugin.pri)
 include(../../plugins/analyzerbase/analyzerbase.pri)
@@ -12,8 +14,6 @@ include(../../plugins/remotelinux/remotelinux.pri)
 include(../../libs/qmljsdebugclient/qmljsdebugclient.pri)
 include(../../libs/extensionsystem/extensionsystem.pri)

-QT += network script declarative
-
 include(canvas/canvas.pri)

 SOURCES += \
--- a/src/plugins/texteditor/texteditor.pro
+++ b/src/plugins/texteditor/texteditor.pro
@@ -2,6 +2,7 @@ TEMPLATE = lib
 TARGET = TextEditor
 DEFINES += TEXTEDITOR_LIBRARY
 QT += xml network
+greaterThan(QT_MAJOR_VERSION, 4): QT += printsupport
 include(../../qtcreatorplugin.pri)
 include(texteditor_dependencies.pri)
 INCLUDEPATH += generichighlighter \
--- a/src/shared/qtsingleapplication/qtsingleapplication.pri
+++ b/src/shared/qtsingleapplication/qtsingleapplication.pri
@@ -4,6 +4,7 @@ HEADERS		+= $$PWD/qtsingleapplication.h $$PWD/qtlocalpeer.h
 SOURCES		+= $$PWD/qtsingleapplication.cpp $$PWD/qtlocalpeer.cpp

 QT *= network
+greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

 gotqtlockedfile = $$find(HEADERS, .*qtlockedfile.h)
 isEmpty(gotqtlockedfile):include(../qtlockedfile/qtlockedfile.pri)
--- a/src/shared/symbianutils/symbianutils.pri
+++ b/src/shared/symbianutils/symbianutils.pri
@@ -1,7 +1,13 @@
 INCLUDEPATH *= $$PWD

 QT += network
-win32:include(../../private_headers.pri)
+win32 {
+    greaterThan(QT_MAJOR_VERSION, 4) {
+        QT += core-private
+    } else {
+        include(../../private_headers.pri)
+    }
+}

 # Input
 HEADERS += $$PWD/symbianutils_global.h \
--- a/src/tools/qmlprofilertool/qmlprofilertool.pro
+++ b/src/tools/qmlprofilertool/qmlprofilertool.pro
@@ -1,3 +1,4 @@
+QT       = core
 include(../../../qtcreator.pri)
 include(../../rpath.pri)

@@ -5,7 +6,6 @@ TEMPLATE = app
 TARGET   = qmlprofiler
 DESTDIR = $$IDE_BIN_PATH

-QT       = core
 CONFIG   += console
 CONFIG   -= app_bundle

--- a/src/tools/qtcdebugger/qtcdebugger.pro
+++ b/src/tools/qtcdebugger/qtcdebugger.pro
@@ -1,5 +1,5 @@
 include(../../shared/registryaccess/registryaccess.pri)
-
+greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
 TARGET = qtcdebugger
 TEMPLATE = app
 SOURCES += main.cpp
--- a/src/tools/qtpromaker/qtpromaker.pro
+++ b/src/tools/qtpromaker/qtpromaker.pro
@@ -1,11 +1,11 @@
+QT        -= gui
+
 include(../../../qtcreator.pri)

 TEMPLATE  = app
 TARGET    = qtpromaker
 DESTDIR   = $$IDE_LIBEXEC_PATH

-QT        -= gui
-
 CONFIG    += console warn_on
 CONFIG    -= app_bundle

--- a/tests/auto/aggregation/aggregation.pro
+++ b/tests/auto/aggregation/aggregation.pro
@@ -1,3 +1,4 @@
+QT -= gui
 include(../qttest.pri)
 INCLUDEPATH += $$IDE_SOURCE_TREE/src/libs/aggregation
 include($$IDE_SOURCE_TREE/src/libs/aggregation/aggregation.pri)
--- a/tests/auto/debugger/dumpers.pro
+++ b/tests/auto/debugger/dumpers.pro
@@ -1,3 +1,4 @@
+greaterThan(QT_MAJOR_VERSION, 4): QT += core-private
 include(../qttest.pri)
 include($$IDE_SOURCE_TREE/src/libs/symbianutils/symbianutils.pri)
 include($$IDE_SOURCE_TREE/src/shared/json/json.pri)
--- a/tests/auto/profilewriter/profilewriter.pro
+++ b/tests/auto/profilewriter/profilewriter.pro
@@ -1,6 +1,7 @@
+QT -= gui
+
 include(../qttest.pri)
 include(../../../src/shared/proparser/proparser.pri)

 SOURCES += \
    tst_profilewriter.cpp
-QT -= gui
--- a/tests/manual/plain-cplusplus/plain-cplusplus.pro
+++ b/tests/manual/plain-cplusplus/plain-cplusplus.pro
@@ -1,4 +1,5 @@
 QT -= core gui
+greaterThan(QT_MAJOR_VERSION, 4):QT += widgets
 TARGET = plain-c++
 DEFINES += CPLUSPLUS_WITHOUT_QT

--- a/tests/manual/ssh/ssh.pri
+++ b/tests/manual/ssh/ssh.pri
@@ -1,3 +1,5 @@
+QT       = core
+
 include (../../../qtcreator.pri)
 include (../../../src/plugins/coreplugin/coreplugin.pri)

@@ -11,8 +13,6 @@ unix {
    QMAKE_LFLAGS += -Wl,-rpath,\"$$IDE_PLUGIN_PATH/Nokia\"
 }

-QT       += core
-QT       -= gui
 CONFIG   += console
 CONFIG   -= app_bundle
 TEMPLATE = app
--- a/tests/tools/codaclient/codaclient.pro
+++ b/tests/tools/codaclient/codaclient.pro
@@ -1,9 +1,10 @@
 DEFINES += SYMBIANUTILS_INCLUDE_PRI

+QT += network
+
 include(../../../qtcreator.pri)
 include(../../../src/shared/symbianutils/symbianutils.pri)

-QT       += core gui network
 TARGET = codaclient
 TEMPLATE = app
 CONFIG += console
--- a/tests/tools/qml-ast2dot/qml-ast2dot.pro
+++ b/tests/tools/qml-ast2dot/qml-ast2dot.pro
@@ -1,5 +1,5 @@
-include(../../../qtcreator.pri)
 QT = core gui
+include(../../../qtcreator.pri)
 macx:CONFIG -= app_bundle
 TARGET = qml-ast2dot