forked from qt-creator/qt-creator
99a3ddbd23
Moved 3D asset import to puppet to ensure import always uses the correct version of the QtQuick3D. Fixes: QDS-3154 Change-Id: I630a833e7231383b87bf8b7214d3545d12de15ab Reviewed-by: Thomas Hartmann <thomas.hartmann@qt.io> Reviewed-by: Mahmoud Badri <mahmoud.badri@qt.io>
44 lines
1.4 KiB
Plaintext
44 lines
1.4 KiB
Plaintext
QT += core gui widgets qml quick network
|
|
QT += core-private qml-private quick-private gui-private
|
|
|
|
CONFIG += c++17
|
|
win32:!mingw: QMAKE_CXXFLAGS += /std:c++17
|
|
|
|
DEFINES -= QT_CREATOR
|
|
|
|
# This .pri file contains classes to enable a special multilanguage translator
|
|
MULTILANGUAGE_SUPPORT_PRI=$$(MULTILANGUAGE_SUPPORT_PRI)
|
|
!isEmpty(MULTILANGUAGE_SUPPORT_PRI) {
|
|
exists($$(MULTILANGUAGE_SUPPORT_PRI)): message(including \"$$(MULTILANGUAGE_SUPPORT_PRI)\")
|
|
else: error("MULTILANGUAGE_SUPPORT_PRI: \"$$(MULTILANGUAGE_SUPPORT_PRI)\" does not exist.")
|
|
include($$(MULTILANGUAGE_SUPPORT_PRI))
|
|
DEFINES += MULTILANGUAGE_TRANSLATIONPROVIDER
|
|
}
|
|
|
|
include (editor3d/editor3d.pri)
|
|
include (../instances/instances.pri)
|
|
include (instances/instances.pri)
|
|
include (../commands/commands.pri)
|
|
include (../container/container.pri)
|
|
include (../interfaces/interfaces.pri)
|
|
include (../types/types.pri)
|
|
include (../qmlprivategate/qmlprivategate.pri)
|
|
include (iconrenderer/iconrenderer.pri)
|
|
include (import3d/import3d.pri)
|
|
|
|
SOURCES += $$PWD/qml2puppetmain.cpp
|
|
RESOURCES += $$PWD/../qmlpuppet.qrc
|
|
|
|
DISTFILES += Info.plist
|
|
|
|
unix:!openbsd:!osx: LIBS += -lrt # posix shared memory
|
|
|
|
osx {
|
|
CONFIG -= app_bundle
|
|
QMAKE_LFLAGS += -Wl,-sectcreate,__TEXT,__info_plist,$$system_quote($$PWD/Info.plist)
|
|
}
|
|
|
|
osx: target.path = $$INSTALL_LIBEXEC_PATH/qmldesigner
|
|
else: target.path = $$INSTALL_LIBEXEC_PATH
|
|
INSTALLS += target
|