forked from qt-creator/qt-creator
d7058e1afe
We do not build texteditor files in unit-tests so some tricks were required to make ClangFormatIndenter available. First simple unit-test proofs it builds and runs. Change-Id: I81d5ea099bd27fd1c1ed8b5b7877299dcc62a67f Reviewed-by: Nikolai Kosjar <nikolai.kosjar@qt.io>
29 lines
967 B
Plaintext
29 lines
967 B
Plaintext
include(../../../src/shared/clang/clang_installation.pri)
|
|
include(../../../src/shared/clang/clang_defines.pri)
|
|
|
|
!isEmpty(LLVM_VERSION) {
|
|
requires(!isEmpty(LIBCLANG_LIBS))
|
|
equals(LLVM_IS_COMPILED_WITH_RTTI, "NO") : message("LLVM needs to be compiled with RTTI!")
|
|
requires(equals(LLVM_IS_COMPILED_WITH_RTTI, "YES"))
|
|
|
|
DEFINES += CLANG_UNIT_TESTS
|
|
INCLUDEPATH += $$LLVM_INCLUDEPATH
|
|
win32 {
|
|
# set run path for clang.dll dependency
|
|
bin_path = $$LLVM_BINDIR
|
|
bin_path ~= s,/,\\,g
|
|
# the below gets added to later by testcase.prf
|
|
check.commands = cd . & set PATH=$$bin_path;%PATH%& cmd /c
|
|
}
|
|
|
|
LIBS += $$ALL_CLANG_LIBS
|
|
|
|
!contains(QMAKE_DEFAULT_LIBDIRS, $$LLVM_LIBDIR): QMAKE_RPATHDIR += $$LLVM_LIBDIR
|
|
|
|
LLVM_CXXFLAGS ~= s,-g\d?,
|
|
QMAKE_CXXFLAGS_WARN_ON *= $$LLVM_CXXFLAGS_WARNINGS
|
|
QMAKE_CXXFLAGS *= $$LLVM_CXXFLAGS
|
|
|
|
DEFINES += CLANG_COMPILER_PATH=\"R\\\"xxx($$LLVM_BINDIR/clang)xxx\\\"\"
|
|
}
|