forked from qt-creator/qt-creator
b9b1f89ea9
Update text to match the template and UI. Use the \example command instead of \page to have qdoc generate HTML files from the example files. This requires also adding the .pro file. Add an SVG image to the sources and link to it from the text. Change-Id: Ib90798386ee082c9ea2a405b33a4f2a5996a9d2a Reviewed-by: Tim Jenssen <tim.jenssen@theqtcompany.com>
123 lines
4.0 KiB
QML
123 lines
4.0 KiB
QML
/**************************************************************************
|
|
**
|
|
** Copyright (C) 2015 The Qt Company Ltd.
|
|
** Contact: http://www.qt.io/licensing
|
|
**
|
|
** This file is part of Qt Creator
|
|
**
|
|
** You may use this file under the terms of the BSD license as follows:
|
|
**
|
|
** "Redistribution and use in source and binary forms, with or without
|
|
** modification, are permitted provided that the following conditions are
|
|
** met:
|
|
** * Redistributions of source code must retain the above copyright
|
|
** notice, this list of conditions and the following disclaimer.
|
|
** * Redistributions in binary form must reproduce the above copyright
|
|
** notice, this list of conditions and the following disclaimer in
|
|
** the documentation and/or other materials provided with the
|
|
** distribution.
|
|
** * Neither the name of The Qt Company Ltd and its Subsidiary(-ies) nor
|
|
** the names of its contributors may be used to endorse or promote
|
|
** products derived from this software without specific prior written
|
|
** permission.
|
|
**
|
|
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
|
|
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
|
|
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
|
|
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
|
|
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
|
|
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
|
|
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
|
|
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
|
|
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
|
|
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
|
|
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
|
|
**
|
|
**************************************************************************/
|
|
|
|
import QtQuick 2.5
|
|
import QtQuick.Controls 1.4
|
|
|
|
import QtSensors 5.0
|
|
|
|
ApplicationWindow {
|
|
title: qsTr("Accelerate Bubble")
|
|
id: mainWindow
|
|
width: 640
|
|
height: 480
|
|
visible: true
|
|
|
|
menuBar: MenuBar {
|
|
Menu {
|
|
title: qsTr("File")
|
|
MenuItem {
|
|
text: qsTr("&Open")
|
|
onTriggered: console.log("Open action triggered");
|
|
}
|
|
MenuItem {
|
|
text: qsTr("Exit")
|
|
onTriggered: Qt.quit();
|
|
}
|
|
}
|
|
}
|
|
|
|
Image {
|
|
id: bubble
|
|
source: "Bluebubble.svg"
|
|
smooth: true
|
|
property real centerX: mainWindow.width / 2
|
|
property real centerY: mainWindow.height / 2
|
|
property real bubbleCenter: bubble.width / 2
|
|
x: centerX - bubbleCenter
|
|
y: centerY - bubbleCenter
|
|
|
|
Behavior on y {
|
|
SmoothedAnimation {
|
|
easing.type: Easing.Linear
|
|
duration: 100
|
|
}
|
|
}
|
|
Behavior on x {
|
|
SmoothedAnimation {
|
|
easing.type: Easing.Linear
|
|
duration: 100
|
|
}
|
|
}
|
|
}
|
|
Accelerometer {
|
|
id: accel
|
|
dataRate: 100
|
|
active:true
|
|
|
|
onReadingChanged: {
|
|
var newX = (bubble.x + calcRoll(accel.reading.x, accel.reading.y, accel.reading.z) * 0.1)
|
|
var newY = (bubble.y - calcPitch(accel.reading.x, accel.reading.y, accel.reading.z) * 0.1)
|
|
|
|
if (isNaN(newX) || isNaN(newY))
|
|
return;
|
|
|
|
if (newX < 0)
|
|
newX = 0
|
|
|
|
if (newX > mainWindow.width - bubble.width)
|
|
newX = mainWindow.width - bubble.width
|
|
|
|
if (newY < 18)
|
|
newY = 18
|
|
|
|
if (newY > mainWindow.height - bubble.height)
|
|
newY = mainWindow.height - bubble.height
|
|
|
|
bubble.x = newX
|
|
bubble.y = newY
|
|
}
|
|
}
|
|
|
|
function calcPitch(x, y, z) {
|
|
return -(Math.atan(y / Math.sqrt(x * x + z * z)) * 57.2957795);
|
|
}
|
|
function calcRoll(x, y, z) {
|
|
return -(Math.atan(x / Math.sqrt(y * y + z * z)) * 57.2957795);
|
|
}
|
|
}
|