forked from qt-creator/qt-creator
4c614d970b
Exporting DO_NOT_BUILD_QMLDESIGNER disables the build of the QmlDesigner plugin. Change-Id: Ia3809268816cd84ef23b872f8df4709e381b3618 Reviewed-by: Eike Ziller <eike.ziller@theqtcompany.com>
95 lines
1.8 KiB
Prolog
95 lines
1.8 KiB
Prolog
include(../../qtcreator.pri)
|
|
|
|
TEMPLATE = subdirs
|
|
|
|
SUBDIRS = \
|
|
coreplugin \
|
|
texteditor \
|
|
cppeditor \
|
|
bineditor \
|
|
diffeditor \
|
|
imageviewer \
|
|
bookmarks \
|
|
projectexplorer \
|
|
vcsbase \
|
|
perforce \
|
|
subversion \
|
|
git \
|
|
cvs \
|
|
cpptools \
|
|
qtsupport \
|
|
qmakeprojectmanager \
|
|
debugger \
|
|
help \
|
|
cpaster \
|
|
cmakeprojectmanager \
|
|
autotoolsprojectmanager \
|
|
fakevim \
|
|
emacskeys \
|
|
designer \
|
|
resourceeditor \
|
|
genericprojectmanager \
|
|
qmljseditor \
|
|
qmlprojectmanager \
|
|
glsleditor \
|
|
pythoneditor \
|
|
mercurial \
|
|
bazaar \
|
|
classview \
|
|
tasklist \
|
|
analyzerbase \
|
|
qmljstools \
|
|
macros \
|
|
remotelinux \
|
|
android \
|
|
valgrind \
|
|
todo \
|
|
qnx \
|
|
clearcase \
|
|
baremetal \
|
|
ios \
|
|
beautifier \
|
|
qmakeandroidsupport \
|
|
winrt \
|
|
qmlprofiler \
|
|
welcome
|
|
|
|
DO_NOT_BUILD_QMLDESIGNER = $$(DO_NOT_BUILD_QMLDESIGNER)
|
|
isEmpty(DO_NOT_BUILD_QMLDESIGNER) {
|
|
SUBDIRS += qmldesigner
|
|
} else {
|
|
warning("QmlDesigner plugin has been disabled.")
|
|
}
|
|
|
|
|
|
isEmpty(QBS_INSTALL_DIR): QBS_INSTALL_DIR = $$(QBS_INSTALL_DIR)
|
|
exists(../shared/qbs/qbs.pro)|!isEmpty(QBS_INSTALL_DIR): \
|
|
SUBDIRS += \
|
|
qbsprojectmanager
|
|
|
|
# prefer qmake variable set on command line over env var
|
|
isEmpty(LLVM_INSTALL_DIR):LLVM_INSTALL_DIR=$$(LLVM_INSTALL_DIR)
|
|
!isEmpty(LLVM_INSTALL_DIR) {
|
|
SUBDIRS += clangcodemodel
|
|
}
|
|
|
|
isEmpty(IDE_PACKAGE_MODE) {
|
|
SUBDIRS += \
|
|
helloworld #\
|
|
#updateinfo
|
|
#} else:!isEmpty(UPDATEINFO_ENABLE) {
|
|
# SUBDIRS += \
|
|
# updateinfo
|
|
}
|
|
|
|
for(p, SUBDIRS) {
|
|
QTC_PLUGIN_DEPENDS =
|
|
include($$p/$${p}_dependencies.pri)
|
|
pv = $${p}.depends
|
|
$$pv = $$QTC_PLUGIN_DEPENDS
|
|
}
|
|
|
|
linux-* {
|
|
SUBDIRS += debugger/ptracepreload.pro
|
|
}
|