forked from qt-creator/qt-creator
bdc26d9379
It's not Qt Creator. And otherwise the build breaks with a namespaced Qt. Change-Id: Ib30ef86fbc59a02f6fd60d2f0b0b8f4ab452ef6d Reviewed-by: Thomas Hartmann <Thomas.Hartmann@digia.com>
57 lines
1.4 KiB
Plaintext
57 lines
1.4 KiB
Plaintext
|
|
QT += core gui widgets qml quick network
|
|
!isEmpty(QT.webkit.name) {
|
|
QT += webkit
|
|
}
|
|
|
|
!isEmpty(QT.v8.name) {
|
|
QT += v8
|
|
}
|
|
|
|
QT += core-private qml-private quick-private gui-private script-private
|
|
|
|
!isEmpty(QT.v8.name) {
|
|
QT += v8-private
|
|
}
|
|
|
|
!macx {
|
|
CONFIG += c++11
|
|
}
|
|
|
|
DEFINES += QWEAKPOINTER_ENABLE_ARROW
|
|
DEFINES -= QT_CREATOR
|
|
|
|
include (../instances/instances.pri)
|
|
include (instances/instances.pri)
|
|
include (../commands/commands.pri)
|
|
include (../container/container.pri)
|
|
include (../interfaces/interfaces.pri)
|
|
|
|
QT_BREAKPAD_ROOT_PATH = $$(QT_BREAKPAD_ROOT_PATH)
|
|
!isEmpty(QT_BREAKPAD_ROOT_PATH) {
|
|
include($$QT_BREAKPAD_ROOT_PATH/qtbreakpad.pri)
|
|
}
|
|
|
|
SOURCES += $$PWD/qml2puppetmain.cpp
|
|
RESOURCES += $$PWD/../qmlpuppet.qrc
|
|
DEFINES -= QT_NO_CAST_FROM_ASCII
|
|
|
|
OTHER_FILES += Info.plist.in
|
|
macx {
|
|
isEmpty(QTCREATOR_PRI_INCLUDED) {
|
|
# So this .pri file is used by
|
|
# compiling the sources that were deployed to Qt Creator,
|
|
# and the Info.plist was generated by static.pro at build time
|
|
QMAKE_INFO_PLIST = $$PWD/Info.plist
|
|
} else {
|
|
# So this .pri file is used from Qt Creator source tree,
|
|
# and we need to generate the Info.plist
|
|
info.input = $$PWD/Info.plist.in
|
|
info.output = $$DESTDIR/$${TARGET}.app/Contents/Info.plist
|
|
QMAKE_SUBSTITUTES += info
|
|
}
|
|
} else {
|
|
target.path = $$QTC_PREFIX/bin
|
|
INSTALLS += target
|
|
}
|