forked from qt-creator/qt-creator
c63725ff66
When qml(2)puppet is built as part of Qt Creator, we need to generate the Info.plist from Info.plist.in. When it is deployed as source into the Qt Creator build, we need to do that too. Change-Id: I83aa446f19984a51822c46df2ab7f41e78002ad4 Reviewed-by: Thomas Hartmann <Thomas.Hartmann@digia.com>
48 lines
1.3 KiB
Plaintext
48 lines
1.3 KiB
Plaintext
|
|
QT += core gui widgets qml quick network v8
|
|
!isEmpty(QT.webkit.name) {
|
|
QT += webkit
|
|
}
|
|
|
|
QT += core-private qml-private quick-private gui-private script-private v8-private
|
|
|
|
!macx {
|
|
CONFIG += c++11
|
|
}
|
|
|
|
DEFINES += QWEAKPOINTER_ENABLE_ARROW
|
|
|
|
include (../instances/instances.pri)
|
|
include (instances/instances.pri)
|
|
include (../commands/commands.pri)
|
|
include (../container/container.pri)
|
|
include (../interfaces/interfaces.pri)
|
|
|
|
QT_BREAKPAD_ROOT_PATH = $$(QT_BREAKPAD_ROOT_PATH)
|
|
!isEmpty(QT_BREAKPAD_ROOT_PATH) {
|
|
include($$QT_BREAKPAD_ROOT_PATH/qtbreakpad.pri)
|
|
}
|
|
|
|
SOURCES += $$PWD/qml2puppetmain.cpp
|
|
RESOURCES += $$PWD/../qmlpuppet.qrc
|
|
DEFINES -= QT_NO_CAST_FROM_ASCII
|
|
|
|
OTHER_FILES += Info.plist.in
|
|
macx {
|
|
isEmpty(QTCREATOR_PRI_INCLUDED) {
|
|
# So this .pri file is used by
|
|
# compiling the sources that were deployed to Qt Creator,
|
|
# and the Info.plist was generated by static.pro at build time
|
|
QMAKE_INFO_PLIST = $$PWD/Info.plist
|
|
} else {
|
|
# So this .pri file is used from Qt Creator source tree,
|
|
# and we need to generate the Info.plist
|
|
info.input = $$PWD/Info.plist.in
|
|
info.output = $$DESTDIR/$${TARGET}.app/Contents/Info.plist
|
|
QMAKE_SUBSTITUTES += info
|
|
}
|
|
} else {
|
|
target.path = $$QTC_PREFIX/bin
|
|
INSTALLS += target
|
|
}
|