Files
qt-creator/share/qtcreator/qml/qmljsdebugger/qmljsdebugger-lib.pri
Alessandro Portale 7d622f1145 Changing template/qmljsdbg-lib as suggested in QTCREATORBUG-2885
- Renaming the screen orientation enum and keys
- Explicit constructors
- Virtual destructors
- Renamed some occurences of 'Qml' in comments to 'QML'
- Adding descriptive comments to all generated files which should
  not be touched by the user.
- Adding missing license headers to the qmljsdebugger sources

Task-Number: QTCREATORBUG-2885
Reviewed-by: Friedemann Kleint
Reviewed-by: dt
2010-11-01 17:03:46 +01:00

39 lines
879 B
Plaintext

# This file is part of Qt Creator
# It enables debugging of Qt Quick applications
QT += declarative script
INCLUDEPATH += $$PWD/include
DEPENDPATH += $$PWD $$PWD/include editor $$PWD/qt-private
contains(CONFIG, dll) {
DEFINES += BUILD_QMLJSDEBUGGER_LIB
} else {
DEFINES += BUILD_QMLJSDEBUGGER_STATIC_LIB
}
## Input
!contains(DEFINES, NO_JSDEBUGGER) {
HEADERS += \
include/jsdebuggeragent.h \
include/qmljsdebugger_global.h
SOURCES += \
jsdebuggeragent.cpp
}
!contains(DEFINES, NO_QMLOBSERVER) {
include($$PWD/editor/editor.pri)
HEADERS += \
include/qdeclarativeviewobserver.h \
include/qdeclarativeobserverservice.h \
include/qmlobserverconstants.h \
qdeclarativeviewobserver_p.h
SOURCES += \
qdeclarativeviewobserver.cpp \
qdeclarativeobserverservice.cpp
}
OTHER_FILES += qmljsdebugger.pri