forked from qt-creator/qt-creator
46e4ecbd44
Needing to compile Qt tools is a bit of a chore (and at some point a diskspace issue) when building/starting Creator as sanity check for comparing different compiler optimization settings. This is not an officially supported configuration. Change-Id: I628e33eb7137f09ecfebbd27453de548bac2fde5 Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@qt.io> Reviewed-by: Eike Ziller <eike.ziller@qt.io>
21 lines
566 B
Prolog
21 lines
566 B
Prolog
TEMPLATE = subdirs
|
|
SUBDIRS = qtcreator/static.pro
|
|
|
|
defineTest(hasLupdate) {
|
|
cmd = $$eval(QT_TOOL.lupdate.binary)
|
|
isEmpty(cmd) {
|
|
cmd = $$[QT_HOST_BINS]/lupdate
|
|
contains(QMAKE_HOST.os, Windows):exists($${cmd}.exe): return(true)
|
|
contains(QMAKE_HOST.os, Darwin):exists($${cmd}.app/Contents/MacOS/lupdate): return(true)
|
|
exists($$cmd): return(true)
|
|
} else {
|
|
exists($$last(cmd)): return(true)
|
|
}
|
|
return(false)
|
|
}
|
|
|
|
hasLupdate(): SUBDIRS += qtcreator/translations
|
|
|
|
DISTFILES += share.qbs \
|
|
../src/share/share.qbs
|