forked from qt-creator/qt-creator
770ab68c45
Change-Id: Iaa7a744ecf13e011addc573a381ea523d2d50a55 Reviewed-by: Thomas Hartmann <Thomas.Hartmann@digia.com>
40 lines
910 B
Prolog
40 lines
910 B
Prolog
TARGET = qml2puppet
|
|
|
|
TEMPLATE = app
|
|
|
|
QT += core gui qml quick network v8
|
|
contains (QT_CONFIG, webkit) {
|
|
QT += webkit
|
|
}
|
|
|
|
QT += core-private qml-private quick-private gui-private script-private v8-private
|
|
|
|
DEFINES += QWEAKPOINTER_ENABLE_ARROW
|
|
|
|
include(../../../../../qtcreator.pri)
|
|
DESTDIR = $$[QT_INSTALL_BINS]
|
|
include(../../../../../src/rpath.pri)
|
|
|
|
include (instances/instances.pri)
|
|
include (../commands/commands.pri)
|
|
include (../container/container.pri)
|
|
include (../interfaces/interfaces.pri)
|
|
|
|
QT_BREAKPAD_ROOT_PATH = $$(QT_BREAKPAD_ROOT_PATH)
|
|
!isEmpty(QT_BREAKPAD_ROOT_PATH) {
|
|
include($$QT_BREAKPAD_ROOT_PATH/qtbreakpad.pri)
|
|
}
|
|
|
|
SOURCES += main.cpp
|
|
RESOURCES += ../qmlpuppet.qrc
|
|
|
|
OTHER_FILES += Info.plist.in
|
|
macx {
|
|
info.input = Info.plist.in
|
|
info.output = $$DESTDIR/$${TARGET}.app/Contents/Info.plist
|
|
QMAKE_SUBSTITUTES += info
|
|
} else {
|
|
target.path = /bin
|
|
INSTALLS += target
|
|
}
|