forked from qt-creator/qt-creator
7de7eb6bca
Don't instantiate repeating boilerplate item data in some cases (such as large arrays). This makes it necessary to access parent WatchItems in a lot more cases than before and needs another separation of WatchItem/WatchModel code to keep the dumper autotests in a functional state. For a plain std::vector<int> with 1 mio items this reduces extraction time from more than 2 minutes to about 3 seconds. Change-Id: I175c5f6ee90434a6e85342d8bb71bd10a04dd271 Reviewed-by: Christian Stenger <christian.stenger@theqtcompany.com> Reviewed-by: David Schulz <david.schulz@theqtcompany.com>
46 lines
1.1 KiB
Prolog
46 lines
1.1 KiB
Prolog
QT = core network
|
|
|
|
QTC_LIB_DEPENDS += utils
|
|
|
|
include(../qttest.pri)
|
|
|
|
win32-msvc* {
|
|
LIBS *= -L$$IDE_PLUGIN_PATH
|
|
DEFINES += Q_PLUGIN_PATH=\"\\\"$$IDE_PLUGIN_PATH\\\"\"
|
|
|
|
CDBEXT_PATH = $$IDE_BUILD_TREE\\$$IDE_LIBRARY_BASENAME
|
|
# replace '\' with '\\'
|
|
DEFINES += CDBEXT_PATH=\"\\\"$$replace(CDBEXT_PATH, \\\\, \\\\)\\\"\"
|
|
}
|
|
|
|
DEBUGGERDIR = $$IDE_SOURCE_TREE/src/plugins/debugger
|
|
DUMPERDIR = $$IDE_SOURCE_TREE/share/qtcreator/debugger
|
|
|
|
include($$IDE_SOURCE_TREE/src/rpath.pri)
|
|
|
|
|
|
SOURCES += \
|
|
$$DEBUGGERDIR/debuggerprotocol.cpp \
|
|
$$DEBUGGERDIR/simplifytype.cpp \
|
|
$$DEBUGGERDIR/watchdata.cpp \
|
|
$$DEBUGGERDIR/watchutils.cpp \
|
|
tst_dumpers.cpp
|
|
|
|
HEADERS += \
|
|
$$DEBUGGERDIR/debuggerprotocol.h \
|
|
$$DEBUGGERDIR/simplifytype.h \
|
|
$$DEBUGGERDIR/watchdata.h \
|
|
$$DEBUGGERDIR/watchutils.h
|
|
|
|
!isEmpty(vcproj) {
|
|
DEFINES += DUMPERDIR=\"$$DUMPERDIR\"
|
|
} else {
|
|
DEFINES += DUMPERDIR=\\\"$$DUMPERDIR\\\"
|
|
}
|
|
|
|
INCLUDEPATH += $$DEBUGGERDIR
|
|
DEFINES += QT_NO_CAST_FROM_ASCII
|
|
|
|
# clang 3.5 does not like to optimize long functions.
|
|
clang: QMAKE_CXXFLAGS_RELEASE =
|