Make deployqt target recursive

So perfparser's deploy target is triggered too

Change-Id: I131a23b46127130967767fd7fee629ac5a97b17a
Reviewed-by: Ulf Hermann <ulf.hermann@qt.io>

qtcreator.pro

@@ -150,4 +150,7 @@ win32 {
     bindist_installer.commands ~= s,/,\\\\,g
 }
 
+deployqt.CONFIG += recursive
+deployqt.recurse = src
+
 QMAKE_EXTRA_TARGETS += deployqt bindist bindist_installer bindist_debug

src/app/app.pro

@@ -52,3 +52,5 @@ DISTFILES += qtcreator.rc \
 QMAKE_SUBSTITUTES += $$PWD/app_version.h.in
 
 CONFIG += no_batch
+
+QMAKE_EXTRA_TARGETS += deployqt # dummy

src/libs/libs.pro

@@ -48,3 +48,5 @@ win32: isEmpty(QTC_SKIP_CDBEXT) {
         message("environment variable pointing to your CDB installation.")
     }
 }
+
+QMAKE_EXTRA_TARGETS += deployqt # dummy

src/plugins/plugins.pro

@@ -133,3 +133,5 @@ for(p, SUBDIRS) {
 linux-* {
      SUBDIRS += debugger/ptracepreload.pro
 }
+
+QMAKE_EXTRA_TARGETS += deployqt # dummy

src/shared/shared.pro

@@ -0,0 +1,28 @@
+TEMPLATE = subdirs
+
+QBS_DIRS = \
+    qbscorelib \
+    qbsqtprofilesetup \
+    qbsapps \
+    qbslibexec \
+    qbsplugins \
+    qbsstatic
+
+qbscorelib.subdir = qbs/src/lib/corelib
+qbsqtprofilesetup.subdir = qbs/src/lib/qtprofilesetup
+qbsqtprofilesetup.depends = qbscorelib
+qbsapps.subdir = qbs/src/app
+qbsapps.depends = qbsqtprofilesetup
+qbslibexec.subdir = qbs/src/libexec
+qbslibexec.depends = qbscorelib
+qbsplugins.subdir = qbs/src/plugins
+qbsplugins.depends = qbscorelib
+qbsstatic.file = qbs/static.pro
+
+exists(qbs/qbs.pro) {
+    isEmpty(QBS_INSTALL_DIR):QBS_INSTALL_DIR = $$(QBS_INSTALL_DIR)
+    isEmpty(QBS_INSTALL_DIR):SUBDIRS += $$QBS_DIRS
+}
+TR_EXCLUDE = qbs
+
+QMAKE_EXTRA_TARGETS += deployqt # dummy

src/src.pro

@@ -1,36 +1,16 @@
-include(../qtcreator.pri)
-
 TEMPLATE  = subdirs
 CONFIG   += ordered
 
-QBS_DIRS = \
-    qbscorelib \
-    qbsqtprofilesetup \
-    qbsapps \
-    qbslibexec \
-    qbsplugins \
-    qbsstatic
-
-qbscorelib.subdir = shared/qbs/src/lib/corelib
-qbsqtprofilesetup.subdir = shared/qbs/src/lib/qtprofilesetup
-qbsqtprofilesetup.depends = qbscorelib
-qbsapps.subdir = shared/qbs/src/app
-qbsapps.depends = qbsqtprofilesetup
-qbslibexec.subdir = shared/qbs/src/libexec
-qbslibexec.depends = qbscorelib
-qbsplugins.subdir = shared/qbs/src/plugins
-qbsstatic.file = shared/qbs/static.pro
-
-exists(shared/qbs/qbs.pro) {
-    isEmpty(QBS_INSTALL_DIR):QBS_INSTALL_DIR = $$(QBS_INSTALL_DIR)
-    isEmpty(QBS_INSTALL_DIR):SUBDIRS += $$QBS_DIRS
-}
-TR_EXCLUDE = shared/qbs
-
 SUBDIRS += \
+    shared \
     libs \
     app \
     plugins \
     tools \
     share/qtcreator/data.pro \
     share/3rdparty/data.pro
+
+# delegate deployqt target
+deployqt.CONFIG += recursive
+deployqt.recurse = shared libs app plugins tools
+QMAKE_EXTRA_TARGETS += deployqt

src/tools/tools.pro

@@ -81,3 +81,8 @@ exists(perfparser/perfparser.pro) {
 }
 
 OTHER_FILES += tools.qbs
+
+# delegate deployqt target
+deployqt.CONFIG += recursive
+deployqt.recurse = perfparser
+QMAKE_EXTRA_TARGETS += deployqt